;Operadores Relacionales
;entre un registro y un literal.

;Esta macro compara un registro con un literal,
;salta si [file] <> lit.
FdistintoL	macro	file, lit, jump_to
	movf	file, W
	xorlw	lit
	btfss	STATUS, Z
	goto	jump_to
		endm

;Esta macro compara un registro con un literal,
;salta si [file] = lit.
FigualL		macro	file, lit, jump_to
	movf	file, W
	xorlw	lit
	btfsc	STATUS, Z
	goto	jump_to
		endm

;Esta macro compara un registro con un literal,
;salta si [file] >= lit.
Fmayor_iL	macro	file, lit, jump_to
	movlw	lit
	subwf	file, W
	btfsc	STATUS, C
	goto	jump_to
		endm

;Esta macro compara un registro con un literal,
;salta si [file] > lit.
FmayorL		macro	file, lit, jump_to
	movf	file, W	
	sublw	lit
	btfss	STATUS, C
	goto	jump_to
		endm

;Esta macro compara un registro con un literal,
;salta si [file] <= lit.
Fmenor_iL	macro	file, lit, jump_to
	movf	file, W	
	sublw	lit
	btfsc	STATUS, C
	goto	jump_to
		endm

;Esta macro compara un registro con un literal,
;salta si [file] < lit.
FmenorL		macro	file, lit, jump_to
	movlw	lit
	subwf	file, W
	btfss	STATUS, C
	goto	jump_to
		endm

;Operadores Relacionales
;entre registros.

;Esta macro compara el registro origen con el
;registro destino, salta si [fileo] <> [filed].
FdistintoF	macro	fileo, filed, jump_to
	movf	fileo, W
	xorwf	filed, W
	btfss	STATUS, Z
	goto	jump_to
		endm

;Esta macro compara el registro origen con el
;registro destino, salta si [fileo] = [filed].
FigualF		macro	fileo, filed, jump_to
	movf	fileo, W
	xorwf	filed, W
	btfsc	STATUS, Z
	goto	jump_to
		endm

;Esta macro compara el registro origen con el
;registro destino, salta si [fileo] >= [filed].
Fmayor_iF	macro	fileo, filed, jump_to
	movf	filed, W
	subwf	fileo, W
	btfsc	STATUS, C
	goto	jump_to
		endm

;Esta macro compara el registro origen con el
;registro destino, salta si [fileo] > [filed].
FmayorF		macro	fileo, filed, jump_to
	movf	fileo, W
	subwf	filed, W	
	btfss	STATUS, C
	goto	jump_to
		endm

;Esta macro compara el registro origen con el
;registro destino, salta si [fileo] <= [filed].
Fmenor_iF	macro	fileo, filed, jump_to
	movf	fileo, W
	subwf	filed, W	
	btfsc	STATUS, C
	goto	jump_to
		endm

;Esta macro compara el registro origen con el
;registro destino, salta si [fileo] < [filed].
FmenorF		macro	fileo, filed, jump_to
	movf	filed, W
	subwf	fileo, W
	btfss	STATUS, C
	goto	jump_to
		endm

Sumar		macro	Registro, literal
	nop
	movlw	literal
	addwf	Registro, F
	nop
		endm