'Programa 6.1: Control PID con StampPlot

'********* CONFIGURACIÓN DEL CONTROL PID ****************

SP CON 990 ' Temp deseada en décimas de grado

Rango CON 20 ' Rango en décimas (20=2F)

B CON 50 ' Configuración de excitación de polarización

Kp CON 0 ' Ganancia Proporcional en décimas (10= ganancia de 1)

Ki CON 0 ' Ganancia Integral en décimas (1= ganancia de 0,1)

Ti CON 24 ' Tiempo de Reset Interal (1=~5 segundos)

Kd CON 0 ' Ganancia Derivativa

MinA CON 75 ' Valor Min. Del eje Y analógico

MaxA CON 120 ' Valor Max. Del eje X analógico

MaxT CON 600 ' Max. Tiempo en segundos del eje X

'*************************************************

'***** Configura graficador

PAUSE 2000

DEBUG "!TITL Control PID ",CR ' Título

DEBUG "!RSET",CR ' Reinicia el gráfico

DEBUG "!PNTS 1000",CR ' 1000 puntos de datos

DEBUG "!TMAX ",DEC MaxT,CR ' Tiempo max.

DEBUG "!AMAX ",DEC MaxA,CR ' Max. analógico

DEBUG "!AMIN ",DEC MinA,CR ' Min. analógico

DEBUG "!AMUL .1",CR ' Multiplicador analógico 0,1

DEBUG "!TSMP ON",CR ' Habilita temporizador

DEBUG "!SAVM ON",CR ' Guarda mensajes en archivo

DEBUG "!CLMM",CR ' Limpia min/max en el reset

DEBUG "!SHFT ON",CR ' Habilita desplazamiento de gráfico

DEBUG "!PLOT ON",CR ' Habilita graficador

' Muestra la configuración del excitador

DEBUG "!USRS SP=",dec SP," Kp=",dec Kp," Ki=",dec Ki," Ti=",dec Ti," Kd=",dec Kd,CR

DEBUG "!RSET",CR ' Reinicia el gráfico

' ************** Define constantes y variables

CS CON 3 ' Chip select del 0831 activo bajo en P3 del BS2

CLK CON 4 ' Clock del BS2 (P4) al 0831
Dout CON 5 ' Salida serial de datos del 0831 al BS2 (P5)

Calentador CON 8 ' Pin para controlar el calentador

Datain VAR BYTE ' Variable para almacenar el número entrante (0 a 255)

Temp VAR WORD ' Almacena valor convertido que representa la Temp.

TempRango CON 5000 ' Rango completo en décimas de grado.

Offset CON 700 ' Temperatura mínima. @Offset, ADC = 0

Signo VAR WORD ' Almacena el signo de los cálculos

Excitacion VAR WORD ' Cantidad de excitación total

Err VAR WORD ' Cantidad de Error

P VAR WORD ' Cantidad de excitación Proporcional

I VAR WORD ' Cantidad de excitación Integral
D VAR WORD ' Cantidad de excitación Derivativa

ContadorPWM VAR BYTE ' Contador para registrar tiempo de aplicación de PWM
UltimoErr VAR WORD ' Almacena temperatura anterior para control derivativo

UltimoErr = 0

ContadorInt VAR BYTE ' Variable para contar ciclos de excitación integral

TiempoPWM CON 20 ' Variable que define cuanto durará la excit. PWM

' (20=~5 segundos)

Ei VAR WORD ' Error acumulativo para cálculo integral

Ei = 0 ' Limpia error acumulativo

'*************** Bucle principal

Principal:

GOSUB Obtenerdato

GOSUB Calc_Temp

GOSUB Calc_Excitacion

GOSUB Grafica_Datos

GOSUB Excitacion_Calentador

GOTO Principal

Obtenerdato: ' Adquiere conversión del 0831

LOW CS ' Habilita el chip

LOW CLK ' Prepara línea de clock.

SHIFTIN Dout, CLK, msbpost,[Datain\9] ' Lee datos

HIGH CS ' conversión

RETURN

Calc_Temp: ' Convierte el valor digital en Temp.

Temp = TempRango/255 * Datain/10 + Offset ' basándose en las variables Rango y

RETURN 'Offset.

Calc_Excitacion:

GOSUB ErrorCalc ' Cálculos de Error

GOSUB PropCalc ' Calcula error proporcional

GOSUB IntCalc ' Calcula error Integral

GOSUB DerivCalc ' Calcula error Derivativo

Excitacion = (B + P + I + D) ' Calcula excitación total
Signo = Excitacion ' Ajuste de signo para max 100 min 0

GOSUB PoneSigno

Excitacion = ABS Excitacion MAX 100

IF Signo = 1 THEN ExcitListo

Excitacion = 0

ExcitListo:

RETURN

'********* Excitacion del calentador

Excitacion_Calentador:

FOR ContadorPWM = 1 TO TiempoPWM ' Aplica PWM durante 220 mSec por cada repetición

PWM Calentador, excitacion * 255/100,220

NEXT

RETURN

'********* Grafica datos

Grafica_Datos:
DEBUG DEC Temp,CR

'** Mensaje de salida con formato de las lecturas (4 líneas)

DEBUG "Deseada:", DEC SP," Temp:", DEC Temp

DEBUG " %Err:",SDEC Err," %B=", DEC B, " %P=", SDEC P

DEBUG " %I=",SDEC I," %D=", SDEC D

DEBUG " %Excitación:",SDEC Excitacion, CR

'** Mensaje de salida separado por comas para importar en hoja de cálculo

' DEBUG ",",DEC Temp,",",SDEC Err,",",SDEC P,",",SDEC I,",",SDEC D,",",SDEC Excitacion,CR

RETURN

'********** Calcula %Error - Signo ajustado

ErrorCalc:

Err = (SP - Temp) ' Calcula error de la temperatura

Signo = Err

GOSUB PoneSigno

Err = ABS Err*100/Rango ' Calcula % error

Err = Err * Signo

RETURN

'*********** Excitación Proporcional - Signo ajustado

PropCalc:

Signo = Err

GOSUB PoneSigno

P = ABS Err * KP + 5/10 ' Err prop= %Err * Kp /10 por escala,

P = P * Signo ' +5 por redondeo

RETURN

'********** Excitación Integral - Signo ajustado

IntCalc:

Ei = Ei + Err ' Acumula %err

ContadorInt = ContadorInt + 1 ' Incrementa contador

IF ContadorInt < Ti Then IntListo

Signo = Ei

Gosub PoneSigno

Ei = ABS Ei / Ti ' Encuentra error promedio

Ei = Ei * Ki + 5 /10 ' Int err = Int err * Ki

Ei = Ei * Signo

I = I + Ei ' Suma error a Int err total

Signo = I

GOSUB PoneSigno

I = ABS I MAX 100 ' limita a 100

I = I * Signo

ContadorInt = 0 ' Reinicia contador y acumulador

Ei = 0

IntListo:

RETURN

'*********** Excitación Derivativa

DerivCalc:

D = (Err-UltimoErr) * KD ' Calcula excitación derivativa

' basándose en la diferencia del último error
DerivListo

UltimoErr = Err ' Almacena error actual para el próximo cálculo

RETURN

'********** Determina el signo de un valor

PoneSigno:

IF Signo.bit15 = 0 THEN SignoPos ' Si signobit es 1, entonces es negativo

Signo = -1

Return

SignoPos:

Signo = 1

SignoListo:

Return
