Publicado por: pachopic en 02 de Septiembre de 2004, 06:38:00
Alguein podria explicarme cuales son los pasos para crear una libreria en ensamblador,por ejemplo para un retardo de tiempo,
o para manejar una lcd, ademas como se invoca en un programa que se realice con ellas, como darle los parametros de entrada..
GRACIAS..
Publicado por: odukec en 02 de Septiembre de 2004, 08:18:00
Es muy facil.. solo tienes que abrir el bloc de notas, escribes las variables que necesiten tus rutinas, luego escribes las rutinas, por ejemplo, lcd_inicializacion..., lcd_envia_caracter, lcd_delay.. etc, las guardas poniendole un nombre digamos lcd.h, y luego en el programa que las vallas a usar simplemente pones un "include "C:directorio donde esta la libreria"", aca pongo un ejemplo para la lcd.. esto lo colocas en bloc de notas, y le pones un nombre puede ser LCD.INC o LCD.H bueno tu veras.
Codigo:
; ///////////////////////////////////////////////////////////////////////
; ////
; Este simplemente lo agregas al programa para usar las rutinas ////
; ////
; Include "LCD.H" ////
; ////
; ///////////////////////////////////////////////////////////////////////
Temp_1 equ 0x38
Temp_2 equ 0x39
;/////////////////////////////////////////////////
;/// Configuración PIC para el LCD. //////
;/////////////////////////////////////////////////
UP_LCD bsf STATUS,RP0 ;Banco 1
clrf PORTD ;Puerto d como salidas
movlw b"00011000"
movwf PORTA ;RA0-RA2 salidas, RA3-RA4 entradas
bcf STATUS,RP0 ;Banco 0
bcf PORTA,0 ;RS=0
bcf PORTA,2 ;E=0
return
;/////////////////////////////////////////////////
;/// Mira Flag de busy //////
;/////////////////////////////////////////////////
LCD_BUSY bsf PORTA,1 ;Pone el LCD en Modo RD
bsf STATUS,RP0
movlw H"FF"
movwf PORTD ;Puerta D como entrada
bcf STATUS,RP0 ;Selecciona el banco 0
bsf PORTA,2 ;Activa el LCD
nop
LCD_BUSY_1 btfsc PORTD,7 ;Chequea bit de Busy
goto LCD_BUSY_1
bcf PORTA,2 ;Desactiva LCD
bsf STATUS,RP0
clrf PORTD ;Puerta B salida
bcf STATUS,RP0
bcf PORTA,1 ;Pone LCD en modo WR
return
;/////////////////////////////////////////////////
;/// Habilitación (Enable) //////
;/////////////////////////////////////////////////
LCD_E bsf PORTA,2 ;Activa E
nop
bcf PORTA,2 ;Desactiva E
return
;/////////////////////////////////////////////////
;/// Escribe un dato en el LCD //////
;/////////////////////////////////////////////////
LCD_DATO bcf PORTA,0 ;Desactiva RS
movwf PORTD ;Valor Ascii a sacar por PortD
call LCD_BUSY ;Espera a que se libere el LCD
bsf PORTA,0 ;Activa RS
goto LCD_E ;Genera pulso de E
;/////////////////////////////////////////////////
;/// Envia Comando al LCD //////
;/////////////////////////////////////////////////
LCD_REG bcf PORTA,0 ;Desactiva RS
movwf PORTD ;Código de comando.
call LCD_BUSY ;LCD libre?.
goto LCD_E ;SI.Genera pulso de E.
;/////////////////////////////////////////////////
;/// Inicializa el LCD //////
;/////////////////////////////////////////////////
LCD_INI movlw b"00111000"
call LCD_REG ;Código de instrucción
call LCD_DELAY ;Temporiza
movlw b"00111000"
call LCD_REG ;Código de instrucción
call LCD_DELAY ;Temporiza
movlw b"00111000"
call LCD_REG ;Código de instrucción
call LCD_DELAY ;Temporiza
movlw b"00000001" ;Borra LCD y Home.
call LCD_REG
return
;/////////////////////////////////////////////////
;/// Delay para inicialización //////
;/////////////////////////////////////////////////
LCD_DELAY: clrwdt
movlw .10
movwf Temp_1
clrf Temp_2
LCD_DELAY_1: decfsz Temp_2,F
goto LCD_DELAY_1
decfsz Temp_1,F
goto LCD_DELAY_1
return
Para usarlo en el programa.. primero inicializas el LCD.. haces un
call LCD_INI
O para enviar un dato al LCD
movlw XX
call LCD_DATO
Espero te sirva
Saludos
Publicado por: MGLSOFT en 02 de Septiembre de 2004, 12:43:00
Hasta yo lo entendi !!
Publicado por: pachopic en 05 de Septiembre de 2004, 07:24:00
vaya,
realmente es muy facil gracias por la explicacion..EXITOS..
Publicado por: odukec en 05 de Septiembre de 2004, 11:30:00
Pues que les digo.. me gusta ayudar en lo que pueda a los demas
, y tambien retribuirles un poco la ayuda que ustedes me han dado..Saludos
Publicado por: valdorre en 05 de Septiembre de 2004, 22:23:00
saludos
Publicado por: maunix en 01 de Diciembre de 2005, 07:26:00
En microchip una libreria es precisamente una unit pero ya compilada en formato .lib.
En el manual MPASM, MPLINKER y MPLIB de Microchip explica como crearlas.
Eso si... no son muy útiles que digamos si van a cambiar todo el tiempo los pines de E/S, etc.
Otro tema que no se trata, que lo pueden tener en consideración es el tema de las paginas. Aqui se asume que todas las variables y el código están en las mismas páginas, a tener cuidado con eso! El error más comun al programar pics es equivocarse en las páginas de ram o de program memory.
Se obtiene mayor potencia y versatilidad si se utiliza "relocatable code" que es una forma de programar que permite luego mover el código de una página a otra sin que afecte al software. De esta forma, si pasamos un código de un PIC a otro PIC donde en el otro pic se lo ubica en una página diferente, con un par de retoques queda listo. Esto es muy util cuando se reutilizan mucho ciertas unidades dentro de varios y diversos proyectos.
Publicado por: kuauhtemok en 01 de Diciembre de 2005, 10:28:00
Oye maunix.. podrias poner un ejemplo de lo que dices por favor ?
Te lo agradeceria mucho