MICROPROCESADOR MC68000

[vszener]

Bueno ya se que este post es de microcontroladores pero creo que todos los universitarios de carreras relacionadas con electronica y quizas mas de un aficionado o simpatizantes de los integrados necesiten trabajar con este micro(en asiganuturas como MICROPROCESADORES, SISTEMAS DIGITALES, etc), creo que es un dispositivo de facil aprendizaje y bastante potente y por lo tanto suspuse que seria bueno iniciar un enlace hacia este dispositivo en su parcela del foro jeje dedicada a motorola. La idea es desarrollar programas y simularlos(asi podremos aprender un poquito mas de este fascinante mundo de los integrados), comprender su estructura y por supuesto trabajar con este dispositivo!!!jeje, bueno no se si me quedare solo jeje pero que sepais que intentare ser constante en ejemplos y demas cositas relacionadas con este micro jeje (todo el tiempo posible que me deje los estudios, el trabajo y demas jeje), bueno lo dicho, espero que sea de vuestro agrado y al liooo!!!

     INDICE:

          1. Factorial de un numero     Pagina 1
          2. Iluminacion de led's de izquierda a derecha     Pagina 1
          3. Coche fantastico I (Con tablas)     Pagina 1
          4. Coche fantastico II (Sin tablas)     Pagina 1
          5. Luces      Pagina 1
          6. Iluminacion de 8 led's correlativos     Pagina 1
          7. Switch & Led's     Pagina 1
          8. Switch & 7seg     Pagina 2
          9. Contador     Pagina 2
        10. Slider & Bar     Pagina 2
        11. Slider & Led's     Pagina 2

[vszener]

Bien, para empezar a trabajar necesitaremos un entorno de trabajo para este micro, un software de simulacion para poder comprobar nuestros programitas y ummmmm no se jeje de momento con respecto a software creo que eso es lo basico, asi que aqui teneis enlaces donde se puede descargar el material de trabajo necesario:

http://www.hzeeland.nl/~pfondse/ide68k/index.html ;de aqui se puede bajar un programa llamado IDE68K el cual compila y tiene un entorno de simulacion con los perifericos basicos. La verda que existen otros entornos de trabajo para el 68k pero yo me quedo con este(no es para hacerle publicidad al producto ennn jeje) pero lo veo muy completo con su entorno de simulacion bastante completito tipo barra led"s, switch"s, etc

Bueno, aparte el proteus tb incluye este micro, asi que tb podeis simular desde alli, la direccion el santo "burrito" la tiene para poder descargarse jeje.

El programa IDE68K(aunque posteare mas tarde como funciona) es un programa shareware, es decir no es gratuito, debes registrarte pero TRANKILOS!!!!jeje no caduca ni nada de eso, solamente que al pasado algun tiempo mientras estamos trabajando en la ventana de editor de programa nos sale de vez en cuando una ventanita recordandonos que debemos registrarnos(esa es la unika limitacion), decir que para poder registrarse no hace falta pagar...(cracks???jeje la version anterior del crack vale para esta tb y asi no nos saldra mas la ventanita de registro)

[vszener]

Aqui teneis una pagina del departamento de tecnologia electronica de la universidad de sevilla dedicada a este micro y tiene bastante cositas como manuales y demas cositas:

http://www.dte.us.es/tec_ind/electron/sd/


Si los archivos os piden una clave de apertura: penelope

Seguimos en contacto!!!!

[vszener]

Aqui os subo un archivito en pdf con el set de instrucciones clasificadas, comentadas(en español) y resumidas para tenerlas a mano(yo en su momento las imprimi jeje)


Bueno no me deja subir el archivo.... asi que os dejo el enlace para descargarla y con mas informacion de este micro:
http://www.dte.us.es/tec_inf/itig/microele/INDEX.HTM
Si trasteais en el link de el post anterior llegais tb a esta pagina pero bueno asi os facilito el trabajo y adelantamos camino para poder llegar ya a empezar a meter mano a los programitas y demas jeje

[vszener]

Si os interesa libros de referencia hacia este micro deciros que hay bastantes, algunos mejores que otros jeje aqui algunos libros:

· SISTEMAS DIGITALES: Ingenieria de los microprocesadores 68000
  Antonio Garcia Guerra y Enrique Fenoll Comes

· LA FAMILIA DEL MC 68000
  Julio Septien et all

· DISEÑO Y PROGRAMACION DEL uP 68000 Y PERIFERICOS
  Enrique Colomar Pous et all

Hay mas, pero con el primer libro y el tercero, teneis de sobra para entender todo lo necesario de este micro





 

[vszener]

Bien, llegados a este punto con los softwares instalados, la paginas revisadas y con ilusion en aprender y desarrollar todas nuestras ideas aqui va el primer ejemplo, bastante facilito.
Ej.1. CALCULAR FACTORIAL DE UN NUMERO

;---------------------------------------------------------
;       VsZeNeR"04      07/Julio/04    
;Programa: Factorial de un numero
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       NUM: Numero a factorizar
;                     D0:  Almacenar NUM
;                     D1:  Almacenar variable
;                     VAR: Constante interna del programa
;
;Salida:          D1: Resultado
;
;Resumen:     Programa que calcula factorial de un numero,
;                     si el numero introducido es negativo, el
;                     programa termina.                      
;---------------------------------------------------------

            org     $400         ;lugar de inicio del programa
NUM     dc.l    10              ;numero a factorizar
VAR      dc.l    -1              ;constante interna del programa para ver si el numero       introducido es negativo

main    move.l  NUM,D0          ;almacena en D0 el numero a factorizar: D0<-NUM
          sub.l   #1,D0           ;decremento D0: D0=D0-1
          TST     D0
          BEQ     cero            ;si D0=0 ->numero introducido 1->ve a cero 1!=1
          CMP     VAR,D0          ;compara si el numero introducido es negativo
           BEQ     cero            ;D0=VAR ->numero introducido es 0->ve a cero 0!=1
           BLT     fin             ;numero introducido es negativo ->fin
           move.l  #1,D1           ;almacena en D1 constante 1: D1=1
           move.l  NUM,D0          ;almacena en D0 el numero a factorizar: D0<-NUM
bucle   mulu    D0,D1           ;multiplica sin signo: D1=D0*D1.Factorial no contempla numeros negativos por eso multiplicacion sin signo
          sub.l   #1,D0           ;decremento D0: D0=D0-1
           TST     D0
           BNE     bucle           ;si D0!=0 ->ve a bucle
           BEQ     fin               ;si D0=0 ->fin
cero    move.l  #1,D1         ;almacena el factorial en D1 0!=1!=1
fin    
        end     main

Compilar en el ide68k y simular en el visualicer simulator y listo!!! la verda que al copiar el programa en esta ventana queda algo desordenado ummmm peor bueno haber si puedo subir el programa en asm(si me lo permite el servidor!!! jeje), a seguir programando!!!!

PD: Sigue sin dejarme subir nada

[vszener]

Aqui os podeis descargar el programa factorial d eun numero


Suerte!!!

[vszener]

Vamos con el 2º ejemplito, esta vez vamos a jugar con la barra de led"s que trae el visual simulator, el siguiente programa ilumina led"s de izquierda a derecha, recordar que los perifericos en el 68k se programan como posiciones de memoria. Los led"s se han declarado en el programa en una tabla, tb se puede hacer el mismo programa sin declarar la tabla de direcciones de led"s...ya la pondre!!! pokito a pokoo jeje.

;-------------------------------------------------------------------------------------------
;       VsZeNeR"04       9/julio/04    
;Programa: Iluminacion de 8 Led"s de izquierda a derecha
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       TABLA: Contiene el led que debe encenderse
;               D0:    Registro almacena la constante de retardo
;               A0:    Direccion que apunta a la tabla
;               RET:   Constante interna del programa cuya funcion es suministrar el retardo
;
;Notas:     Subrutina delay: Se le introduce un retardo para que se vea el desplazamiento
;                            de los led"s        
;
;Resumen:   Programa que enciende led de izquierda a derecha                      
;-------------------------------------------------------------------------------------------
        org     $400            ;inicio del programa
*****VARIABLES*****************
tabla   dc.b    %10000000       ;Led 0 on: A0=$400 ->inicio de tabla
        dc.b    %01000000       ;Led 1 on: A0=$401
        dc.b    %00100000       ;Led 2 on: A0=$402
        dc.b    %00010000       ;Led 3 on: A0=$403
        dc.b    %00001000       ;Led 4 on: A0=$404
        dc.b    %00000100       ;Led 5 on: A0=$405
        dc.b    %00000010       ;Led 6 on: A0=$406
        dc.b    %00000001       ;Led 7 on: A0=$407 ->fin de tabla
RET     equ     $FFFFF          ;constante de retardo
*****PROGRAMA******************
main    lea     TABLA,A0        ;carga direccion de tabla en A0
loop    move.b  (A0)+,$E003     ;carga e ilumina led correspondiente e incrementa direccion de A0
        BSR     delay           ;salta a subrutina delay
        CMP     #$407,A0        ;¿fin de tabla?
        BLS     loop            ;no es fin de tabla ->ve a loop
        BRA     main            ;si es fin de tabla ->ve a main
*****RETARDO*******************
delay   move.l  #RET,D0         ;carga constante de retardo en registro D0
loop1   sub.l   #1,D0           ;D0=D0-1
        TST.l   D0              ;¿D0==0?
        BNE     loop1           ;no es igual a cero ->ve a loop1
        rts                     ;si es cero ->fin de subrutina
******************************        
        end     main            ;fin programa

Esto como siempre el copia y pega sale las cosas descentradas...lo subire al almacen y ya os avisare jeje a seguirrr y haber si alguien mas se animaa que voy a coger complejo de monopolista jeje

[vszener]

Bien una mas de led"s, esta vez vamos a simular el colorido del coche fantastico jeje aqui va el codigo(ya sabeis algo desordenado por el copia y pega peor lo subire al almacen y os avisare)

;-------------------------------------------------------------------------------------------
;       VsZeNeR"04       9/julio/04    
;Programa: Iluminacion de 8 Led"s de derecha a izquierda y viceversa
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       TABLA: Contiene el led que debe encenderse
;               D0:    Registro almacena la constante de retardo
;               A0:    Direccion que apunta a la tabla
;               RET:   Constante interna del programa cuya funcion es suministrar el retardo
;
;Notas:     Subrutina delay: Se le introduce un retardo para que se vea el desplazamiento
;                            de los led"s        
;
;Resumen:   Programa que enciende led de derecha a izquierda viceversa(Coche fantastico)                      
;-------------------------------------------------------------------------------------------
        org     $400            ;inicio del programa  
******VARIABLES****************
TABLA   dc.b    %00000001       ;Led 0 on: A0=$400 ->inicio de tabla        
        dc.b    %00000010       ;Led 1 on: A0=$401
        dc.b    %00000100       ;Led 2 on: A0=$402
        dc.b    %00001000       ;Led 3 on: A0=$403
        dc.b    %00010000       ;Led 4 on: A0=$404
        dc.b    %00100000       ;Led 5 on: A0=$405
        dc.b    %01000000       ;Led 6 on: A0=$406
        dc.b    %10000000       ;Led 7 on: A0=$407 ->fin de tabla
RET     equ     $FFFFF          ;constante de retardo
******PROGRAMA*****************        
main    lea     TABLA,A0        ;carga direccion de la tabla en A0
loop    move.b  (A0)+,$E003     ;carga e ilumina el LED"S correspondiente e incrementa direccion A0
        bsr     delay           ;salta a subrutina delay
        CMP     #$407,A0        ;¿es el final de la tabla?
        BLS     loop            ;no es el final ->ve a loop
*******FIN DE TABLA************ ;ilumina led"s de izquierda a derecha
lop1    move.b  -(A0),$E003     ;decrementa direccion A0 y carga e ilumina el correspondiente LED"S
        bsr     delay           ;salta a subrutina delay
        CMP     #$400,A0        ;¿es el principio de la tabla?
        BHI     lop1            ;no es el principio ->ve a lop1
        BRA     loop            ;si es el principio ->ve a loop
*******RETARDO*****************
delay   move.l  #RET,D0         ;carga la constante de retardo en registro D0
lop2    sub.l   #1,D0           ;D0=D0-1
        TST.l   D0              ;¿D0==0?
        BNE     lop2            ;no es igual a cero ->ve a lop2
        rts                     ;si es igual a cero ->fin de subrutina
*******************************
        end     main

Esta programado tb con tablas la direcciones de los led"s a iluminar, como dije en el anterior ejemplo se puede programar sin tablas por lo tanto ahorra memoria...ya pondre la programacion sin tabla, de momento asi pokito a poko iremos progresando a mass....a seguir programando!!!

[vszener]

Ya espero que los que esten programando aunque en silencio ummmm jeje tengan algo de isea, los ejemplos anteriores han sido programados siguiendo tablas, es decir, en el 68k los perifericos, como ya mencione, se programan y se tratan como direcciones de memoria, or lo tanto definiendo su direccion adecuadamente podremos manejarlos. Se pueden manejar por tablas, es decir, se definen todas las direcciones de los perifeicos segun lo que querramos hacer, pero como mencionado tb se pueden hacer sin tablas(sin definir todas las direcciones) mediante instrucciones de rotacion y desplazamiento. Aqui os dejo un ejemplo de la iluminacion del coche fantastico pero esta vez sin tablas.

;-------------------------------------------------------------------------------------------
;       VsZeNeR"04       14/julio/04    
;Programa: Desplazamiento led"s de derecha a izquierda y viceversa sin tabla(coche fantastico)
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       D0:    Registro encargado almacenar led encendido
;               D1:    Registro encargado almacenar constante de retardo
;               RET:   Constante interna del programa cuya funcion es suministrar el retardo
;
;Notas:     Subrutina delay: Genera un retardo para poder visualizar los led"s
;                                    
;
;Resumen:   Programa que enciende 7 led"s de derecha a izquierda y viceversa sin tabla                      
;-------------------------------------------------------------------------------------------
        org     $400            ;inicio programa
*****VARIABLES*****************
RET     equ     $FFFFF          ;constante de retardo
*******************************
main    move.b  #%00000001,D0   ;cargo primer led se va encender en registro D0  
loop    move.b  D0,$E003        ;enciende led correspondiente
        BSR     delay           ;ve a subrutina delay  
        asl     #1,D0           ;desplazamiento hacia izquierda del bit 1(led on)
        CMP     #$100,D0        ;¿es el led 7 on? fin de led"s $100=000100000000 fin led"s  
        BEQ     izqu            ;si es led 7 ->ve a izqu  
        BNE     loop            ;no es led 7 ->ve a loop
*****IZQU->DERECHA*************
izqu    asr     #1,D0           ;desplazamiento hacia derecha del bit 1(led on)
        move.b  D0,$E003        ;enciende led correspondiente
        BSR     delay           ;ve a subrutina delay
        CMP     #$1,D0          ;¿es el led 1 on? principio de led"s $1=00000001
        BEQ     loop            ;si es led 1 ->ve a loop
        BNE     izqu            ;no es led 1 ->ve a izqu
*****SUBRUTINA DELAY***********
delay   move.l  #RET,D1         ;D1=RET
loop1   sub.l   #1,D1           ;D1=D1-1
        TST.l   D1              ;¿D1==0?
        BNE     loop1           ;no es cero ->ve aloop1
        rts                     ;si es cero ->fin de subrutina
*******************************  
        end     main            ;fin programa  

A seguir programando!!!

[vszener]

Lo prometido es deuda, asi que aqui os dejo el enlace con los tres programitas anteriores para poder ser descargados e esta direccion, los programas son:
      1º. Iluminacion led"s simulando colorido coche fantastico(sin tablas)
      2º. Iluminacion led"s simulando colorido coche fantastico(con tablas)
      3º. Iluminacion de led"s derecha a izquierda




 

[vszener]

Vamos otra de led"s jeje aunque creo que ya manejareis los led"s bastante bien aqui teneis otro ejemplito para seguir practicando, esta vez la secuencia de iluminacion es de fuera a dentro:

;-------------------------------------------------------------------------------------------
;       VsZeNeR"04       9/julio/04    
;Programa: Iluminacion de 8 Led"s de los extremos de fuera hacia dentro y viceversa
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       TABLA: Contiene el led que debe encenderse
;               D0:    Registro almacena la constante de retardo
;               A0:    Direccion que apunta a la tabla
;               RET:   Constante interna del programa cuya funcion es suministrar el retardo
;
;Notas:     Subrutina delay: Se le introduce un retardo para que se vea el desplazamiento
;                            de los led"s        
;
;Resumen:   Programa que enciende led de fuera a dentro y viceversa                      
;-------------------------------------------------------------------------------------------
        org     $400            ;inicio del programa
*****VARIABLES*****************
TABLA   dc.b    %10000001       ;Led"s 7y0 on: A0=$400 ->inicio de tabla
        dc.b    %01000010       ;Led"s 6y1 on: A0=$401
        dc.b    %00100100       ;Led"s 5y2 on: A0=$402
        dc.b    %00011000       ;Led"s 4y3 on: A0=$403 ->fin de tabla
RET     equ     $FFFFF          ;constante de retardo
*****PROGRAMA******************
main    lea     TABLA,A0        ;carga direccion de tabla en A0
loop    move.b  (A0)+,$E003     ;carga e ilumina led correspondiente e incrementa direccion de A0
        BSR     delay           ;salta a subrutina delay
        CMP     #$403,A0        ;¿fin de tabla?
        BLS     loop            ;no es fin de tabla ->ve a loop
*****FIN TABLA***************** ;mueve los led"s en sentido contrario
lop1    move.b  -(A0),$E003     ;decrementa direccion de A0 y carga e ilumina led correspondiente
        BSR     delay           ;salto a subrutina delay
        CMP     #$400,A0        ;¿principio de tabla?
        BHI     lop1            ;no es principio tabla ->ve a lop1
        BRA     loop            ;si es principio tabla ->ve a loop
*****RETARDO*******************
delay   move.l  #RET,D0         ;carga constante de retardo en D0
loop2   sub.l   #1,D0           ;D0=D0-1
        TST.l   D0              ;¿D0==0?
        BNE     loop2           ;no es igual a cero ->ve a loop2
        rts                     ;si es cero ->fin subrutina
*******************************
        end     main            ;fin programa

Sin prisas pero sin pausa!!!

[vszener]

Vamos con otro ejemplito de led"s, ya os lo sabreis de memoria programarlos no???jeje pues toma otro ejemplito mas, esta vez se iluminan correlativamente, una secuencia bastante bonita jeje:

;-------------------------------------------------------------------------------------------
;       VsZeNeR"04       9/julio/04    
;Programa: Iluminacion de 8 Led"s correlativamente
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       D0:    Registro encargado iluminar led"s
;               D1:    Registro encargado almacenar cosntante de retardo
;               RET:   Constante interna del programa cuya funcion es suministrar el retardo
;
;Notas:     Subrutina delay: Se le introduce un retardo para que se vea el desplazamiento
;                            de los led"s        
;
;Resumen:   Programa que enciende led"s correlativamente                      
;-------------------------------------------------------------------------------------------
        org     $400            ;inicio programa
*****VARIABLES*****************
RET     equ     $FFFFF          ;constante de retardo
*****PROGRAMA******************
main    move.b  #0,D0           ;D0=0
loop    move.b  D0,$E003        ;carga e ilumina el correspondiente led
        BSR     delay           ;salto a subrutina delay
        add.b   #1,D0           ;D0=D0+1
        CMP     #$0,D0          ;¿estan todos los led"s encendidios?
        BHI     loop            ;no estan todos encendidios ->ve a loop
        BRA     main            ;si estan todos encendidos ->ve a main
*****RETARDO*******************
delay   move.l  #RET,D1         ;cargo constante de retardo en D1
loop1   sub.l   #1,D1           ;D1=D1-1
        TST.l   D1              ;¿D1==0?
        BNE     loop1           ;no es igual a cero ->ve a loop1
        rts                     ;si es igual a cero ->fin de subrutina
*******************************
        end     main            ;fin de programa

Seguimos en contacto, corto y cambio!!!

[vszener]

Bien, ahora ya que sabemos programar los led"s vamos con los switch, este ejemplito enciende el led correspondiente al switch pulsado:

;-------------------------------------------------------------------------------------------
;       VsZeNeR"04       16/julio/04    
;Programa: Led"s y switches
;Simulador MC68000: IDE68K(vs1.35)    
;
;Entrada:       D0:    Registro encargado almacenar led a encender
;              
;
;Resumen:   Programa que enciende led correspondiente al switch seleccionado                      
;-------------------------------------------------------------------------------------------      
        org     $400            ;inicio programa
*****VARIABLES******************
SWITCH  equ     $E001           ;direccion de los switches
LED     equ     $E003           ;direccion de los led"s
*****PROGRAMA*******************
main    move.b  SWITCH,D0       ;carga contenido switch en D0(activado=1 ; desactivado=0)
    move.b  D0,LED          ;enciende led correspondiente a los switches activados
        BRA     main            ;ve a main
        end     main            ;fin programa

Pokito a poko vamos programando!!!

[vszener]

Aqui va el enlace para descargarse los tres ejemplitos anteriores