PIC BASIC del PIC Simulator IDE Oshonsoft (Índice en página 1)

[Goofymza]

hola de nuevo tengo una consulta alguien sabe como utilizar las entradas analogas del 16f628a por que la verdad no la he podido hacer andar a una sola me muetra todaslas entradas del puerto a analagas(ra0, ra1, ra2, ra3) y no me deja hacer comparaciones

[dogflu66]

No he utilizado el modulo comparador, habra que mirar el
data del pic para configurarlo, cuando tenga un rato
echare un vistazo.

[dogflu66]

Este es un ejemplo extraido de la pagina del PSI, usando el modulo comparador.
Es el Example 6 (http://www.oshonsoft.com/picgetstarted.html#6)

Código: vb.net

1. '***************************************************************
2. '****************Analog Comparator Module***********************
3. '***************************************************************
4. Define CONF_WORD = 0x3f10
5. Define CLOCK_FREQUENCY = 4
6.  
7. Symbol comp_change = PIR1.CMIF  'comparator interrupt flag
8.  
9. CMCON = 0x06  'set comparator mode to two common reference comparators with outputs
10. TRISA = 0x07  'set RA0, RA1 and RA2 as inputs, other PORTA pins as outputs
11. VRCON = 0xec  'turn on, configure voltage reference module for 2.5V and connect it to RA2
12. TRISB = 0x00  'set PORTB pins as outputs
13.  
14. loop1:
15.         While Not comp_change  'wait for comparator output change
16.         Wend
17.         PORTB = CMCON  'display CMCON register on PORTB pins, RB6 and RB7 are comparator outputs
18.         comp_change = 0  'reset comparator interrupt flag
19. Goto loop1  'repeat forever
20. End                                              
21. 'http://www.oshonsoft.com/picgetstarted.html#6

[dogflu66]

El ejemplo viene explicado paso a paso para poder ser simulado...

[Goofymza]

hola nuevamente gente gracias dogflu66 por el material la verdad ni lo vi en la pagina
bueno les cuento qual es el problema en la septima linea del ejemplo esta el comando pir1 y a continuacion CMIF quien es el que dice que se debe activar y a que voltage
lo que nesecito saber es si hay alguna forma de configurar CMIF o PIR1 para decirle a que valor de comparacion ejecute las acciones de los pines
desde ya muchas gracias

[dogflu66]

Nunca he utilizado el modulo comparador.
Pere ya puestos cuando termine un par de cosas
lo mirare mas afondo... 

[dogflu66]

Os dejo la solución a un problema muy puntual que me encontré hace
poco en un pequeño proyecto que estoy terminando, tan solo indicar
que genera una trama a 1200baudios mediante la función Serout,
estando el hard basado en un Pic12F675. El pic funciona mediante
su reloj interno a 4Mhz, y el problema estaba en que enviaba siembre
la trama corrompida, estando por otro lado el Soft y el Hard bien,
al final pude encontrar el problema. El data de este micro nos indica
que puede tener hasta +-200Khz de error en la frecuencia del reloj,
asi que la solución fue calibrar el oscilador mediante el registro “osccal”,
el fabricante en este micro nos indica el valor a calibrar. Este valor
esta escrito en la ultima posición de memoria flash del pic, pero el por si
mismo no lo utiliza. Una vez calibrado el sistema funciono correctamente.

El Pic16F88 es distinto del anterior porque su reloj interno esta
calibrado en fabrica. No hay problema en jugar con el registro
porque siempre vuelve al calibrado original si se omite nuestro ajuste.
Aquí dejo el programa para calibrar la rutina generadora de 1000hz.
Como es natural al ejecutar código este tarda un tiempo y genera retrasos,
con este método podemos recalibrar el sistema.

En este caso el registro tiene nombre diferente “osctune” para el
PIC16F88. Con un factor de corrección de 63 corrige todos los retrasos que se generan
al procesar código y queda justo exactamente a la frecuencia deseada.
Después del ajuste del oscilador del 16F88 mediante OSCTUNE pasamos de
generar una frecuencia de 1009hz por el retardo que se tarda en ejecutar el código
a 1000hz  después de la calibración, como se puede observar el calibrado del oscilador
interno de este pic realizado por el fabricante es muy preciso.
Todo esto medido en el pin RB4 mediante un frecuencimetro.

Código: [Seleccionar]

'***************** Placa Entrenadora (PIC EBadic) *****************
'NOMBRE: 16F88_Ejemplo 22
'MICRO: PIC16F88, 8Mhz reloj interno
'Fecha/Autor: 07/07, By COS, PSI v7.41
'Metodo para el calibrado del reloj interno del pic
'******************************************************************
'******************************************************************
Define CONF_WORD = 0x2f50  'Configuración de bits (fuses)
Define CONF_WORD_2 = 0x3ffc  'Configuración de bits (fuses)
Define CLOCK_FREQUENCY = 8  'Frecuencia del reloj en Mhz
'Define SIMULATION_WAITMS_VALUE = 1  'Hace que se ignoren los tiempos de los WaitMs
'Definicion de puertos y modulos ---------
AllDigital  'Los pin de los puertos como I/O
CMCON = 0x07  'Comparador a off
OSCCON = 0x7e  'Set intrc To 8mhz, se usara reloj interno a 8Mhz
'OSCTUNE = 63  'Factor de correcion del reloj
TRISA = 0xff  'Puerto A como entradas
TRISB = 0xff  'puerto B como entradas
TRISB.4 = 0  'RB4 como salida
'Rutina Principal ----------------------
main:  'Bucle infinito
RB4 = 1  '_______Genera una frecuencia de 1Khz
WaitUs 500
RB4 = 0
WaitUs 500  '____
Goto main  'Impide que termine la subrutina principal
End 


[dogflu66]

PD. con el ejemplo pasado "'NOMBRE: 16F88_Pic_EBasic_LCD_Timer1_MidiendoTiempo_10"
se podria medir el tiempo exacto de la rutina para generar 1Khz y tal vez podriamos hacer
un ajuste mas fino.

[dogflu66]

Generando numeros aleatorios (Dado Electronico):

Como este basic no tiene implementado el comando o la función Random.
Vamos a generar nuestra propia rutina para generar números aleatorios.
Se trata de utilizar un timer para generar nuestros números aleatorios.
Programaremos un timer, en este caso el Timer0, para que este continuamente
incrementándose, no activaremos las interrupciones del timer, porque no nos
hace falta en este caso. El Timer0 es utilizado por algunos módulos y funciones,
asi que si utilizamos estos módulos o funciones tendremos que cambiar de timer
como base para obtener estos números..

Activamos el timer y filtramos su resultado para obtener el margen deseado,
en este caso cada vez que pulsemos una tecla obtendremos un numero comprendido entre 1 y 6.

Nota: Este sistema se basa en un contador (TMR0) que se incrementa y reinicia constantemente a una gran velocidad, tarda en realizar un ciclo completo unas pocas decenas o centenares de uSeg.
Un contador por si solo no basta para conseguir el numero aleatorio, si nos basamos solamente en extraer el valor del registro contador del timer utilizado mediante el programa tendríamos siempre la tendencia a repetir la misma lista de resultados, porque el microcontrolador es un entorno finito y ordenado y, esto lo hace predecible; pero si se realiza la lectura del contador solamente cuando se pulsa una tecla (evento humano exterior) se añade el elemento de aleatoriedad que falta. La velocidad con la que varia el contador del timer es tal que por mucho que nos esmeremos resultará realmente dificil predecir el numero que saldrá al pulsar la tecla.

[dogflu66]

El programa:

Código: [Seleccionar]

'***************** Placa Entrenadora (PIC EBadic) ***************************************
'NOMBRE: 16F88_Pic_EBasic_EJEMPLO_23
'Descripcion: Generando numeros aleatorios con el Timer0, Dado Electronico
'Micro: pic16f88 / 8mhz reloj interno
'Version: 1.0
'Fecha/Autor: 22/7/07, By COS, PSI v7.41
'**********************************************************************************
Define CONF_WORD = 0x2f50  'Configuración de bits (fuses)
Define CONF_WORD_2 = 0x3ffc  'Configuración de bits (fuses)
Define CLOCK_FREQUENCY = 8  'Frecuencia del reloj en Mhz
'Define SIMULATION_WAITMS_VALUE = 1  'Hace que se ignoren los tiempos de los WaitMs
'Puertos del LCD-------------------------------------
Define LCD_BITS = 4  'Indicamos que el bus de datos del lcd sera de 4bit
Define LCD_DREG = PORTA  'Bus de datos sera el puerto A
Define LCD_DBIT = 0  'Bus de datos seran los 4 bit menos significativos del puerto A
Define LCD_RSREG = PORTB  'Bit de control RS sera del puerto B
Define LCD_RSBIT = 7  'RB7 como RS
Define LCD_EREG = PORTB  'Bit de control E sera del puerto B
Define LCD_EBIT = 6  'RB6 como E
Define LCD_COMMANDUS = 2000  'Tiempo de espera despues de ejecutar un comando del lcd en uSeg.
Define LCD_DATAUS = 50  'Tiempo de espera despues de enviar un dato al LCD en uSeg.
Define LCD_INITMS = 50  'Tiempo de espera despues de inicializar el Display.
'Definicion de puertos------------------------------------------
ANSEL = %00010000  'Los pin I/O digitales y RA4 analogico
CMCON = 0x07  'Comparador a off
OSCCON = 0x7e  'Set intrc To 8mhz, se usara reloj interno a 8Mhz
TRISA = 0xff  'Puerto A como entradas
TRISB = 0xff  'Puerto B como entradas
'TRISA.4 = 1  'Como entrada (RA4, adc)
'TRISA.6 = 1  'Como entrada (RA6, tecla S1)
'TRISA.5 = 1  'Como entrada (RA5, tecla S2)
TRISB.3 = 0  'Como salida RB3
TRISA.7 = 0  'Como salida RA7
TRISB.0 = 0  'Como salida RB0
PORTB.3 = 1  'Luz lcd a on (RB3)
PORTA.7 = 1  'Led amarillo a off (RA7), negado
PORTB.0 = 1  'Led verde a off (RB0), negado
'Inicialización TIMER0-----------------------------
OPTION_REG.T0CS = 0  'Selecciona reloj interno
OPTION_REG.PSA = 0  'Asigna el prescaler al timer0
'---------------------------------------------------
Lcdinit  'Inicializa el LCD sin cursor.
'Reasignacion de nombres-------------------------
Symbol led_amarillo = PORTA.7  'Led amarillo
Symbol led_verde = PORTB.0  'Led verde
Symbol luz_lcd = PORTB.3  'Iluminacion del lcd
Symbol s1 = RA6  'Tecla S1
Symbol s2 = RA5  'Tecla S2
'Variables generales--------------------------------
Dim random As Byte  'Contendra el numero deseado
'---------------------------------------------------
WaitMs 500  'Espera medio segundo
Lcdout "Pulse una Tecla"  'Imprime en el lcd
'Rutinas Principal ---------------------------------
main:  'Comienza el programa principal
If s1 = 0 Or s2 = 0 Then  'Detecta las teclas
While s1 = 0 Or s2 = 0  'Espera que se suelte la tecla
Wend
random = (TMR0 Mod 6) + 1  'Siendo 6 el numero maximo y +1 porque no queremos que salga el cero.
Lcdcmdout LcdLine2Home  'Cursor del lcd al principio linea 2
Lcdout "El Numero: ", #random, "  "  'Imprime la plantilla y el resultado en el lcd
WaitMs 300  'Espera 0.3 segundo
Endif
Goto main  'Impide que termine el programa principal
End                                               


PD. donde decia "TRISB = 0xf  'puerto B como entradas", ahora dice "TRISB = 0xff  'puerto B como entradas"

[dogflu66]

Esta es una version mas elaborada del programa anterior
Ahora el codigo es mas transportable porque uso la generacion
del numero aleatorio mediante una funcion.

Y recomiendo mirar la forma que uso en esta version para
controlar los led mediante la estructura PROC.

[dogflu66]

El programa:

Código: [Seleccionar]

'***************** Placa Entrenadora (PIC EBadic) ***************************************
'NOMBRE: 16F88_Pic_EBasic_EJEMPLO_23_1
'Descripcion: Generando numeros aleatorios con el Timer0, Dado Electronico
'Micro: PIC16F88 / 8mhz reloj interno
'Fecha/Autor: 22-25/7/07, By COS, PSI v7.41
'Version: 1.1
'Usando Function y Proc
'Se calcula el numero mediante una Funcion.
'El primer numero de entrada de la funcion es el numero maximo y
'el segundo numero de la funcion es el numero minimo.
'nueva rutina para el control de los led mediante Proc.
'Version: 1.0
'Calcula numero aleatorio
'**************************************************************************************
Define CONFIG = 0x2f50  'Configuración bits (Fuses)
Define CONFIG2 = 0x3ffc  'Configuración bits (Fuses)
Define CLOCK_FREQUENCY = 8  'Clock en Mhz
'Define SIMULATION_WAITMS_VALUE = 1  'Activar para simulación
'Puertos del LCD---------------------------------------------
Define LCD_BITS = 4  'indicamos que el bus de datos del lcd sera de 4bit
Define LCD_DREG = PORTA  'el bus de datos sera el puerto A
Define LCD_DBIT = 0  'el bus de datos seran los 4 bit menos significativos del puerto A
Define LCD_RSREG = PORTB  'el bit de control RS sera del puerto B
Define LCD_RSBIT = 7  'se usara el RB7 como RS
Define LCD_EREG = PORTB  'el bit de control E sera del puerto B
Define LCD_EBIT = 6  'se usara el RB6 como E
'Define LCD_RWREG = PORTA 'el bit de control RW sera del puerto A (si se suprime el compilador no protesta)
'Define LCD_RWBIT = 5 'se usara el RA5 como RW (si se suprime el compilador no protesta)
Define LCD_COMMANDUS = 2000  'Tiempo de espera despues de ejecutar un comand del lcd en uSeg.
Define LCD_DATAUS = 50  'Tiempo de espera despues de enviar un dato al LCD en uSeg.
Define LCD_INITMS = 50  'Tiempo de espera despues de inicializar el Display, solo se ejecuta una vez en mSeg.
'Definicion de puertos------------------------------------------
ANSEL = %00010000  'Los pin I/O digitales y RA4 analogico
CMCON = 0x07  'Comparador a off
OSCCON = 0x7e  'Set intrc To 8mhz, se usara reloj interno a 8Mhz
TRISA = 0xff  'Puerto A como entradas
TRISB = 0xff  'Puerto B como entradas
'TRISA.4 = 1  'Como entrada (RA4, adc)
'TRISA.6 = 1  'Como entrada (RA6, tecla S1)
'TRISA.5 = 1  'Como entrada (RA5, tecla S2)
TRISB.3 = 0  'Como salida RB3
TRISA.7 = 0  'Como salida RA7
TRISB.0 = 0  'Como salida RB0
PORTB.3 = 1  'Luz lcd a on (RB3)
PORTA.7 = 1  'Led amarillo a off (RA7), negado
PORTB.0 = 1  'Led verde a off (RB0), negado
'-----------------------------------------------------------------
Lcdinit  'Inicializa el LCD sin cursor.
'Reasignacion de nombres---------------------------------------
Symbol led_amarillo = PORTA.7  'led amarillo
Symbol led_verde = PORTB.0  'led verde
Symbol luz_lcd = PORTB.3  'retroiluminacion del lcd
Symbol s1 = RA6  'tecla S1
Symbol s2 = RA5  'tecla S2
'Variables generales-----------------------------------------------
Dim n_random As Byte  'contendra el numero deseado
'------------------------------------------------------------------
WaitMs 500  'Espera medio segundo
Lcdout "Pulse una Tecla"  'Imprime en el lcd
Call led(_off, _off)  'Inicializa los led a off
n_random = random(0, 0)  'Inicializa random (timer0)
'Rutinas principal ------------------------------------------------
main:  'Comienza el programa principal
If s1 = 0 Then  'Si la tecla es pulsada
While s1 = 0  'Espera mientras esta pulsada la tecla
Wend
Call led(_on, _nc)  'Ilumina led_amarillo, no modifica led verde
n_random = random(6, 1)  'Funcion que genera numero aleatorio
Lcdcmdout LcdLine2Home  'Cursor del lcd al principio linea 2
Lcdout "El Numero: ", #n_random, "  "  'Imprime la plantilla y el resultado en el lcd
WaitMs 300  'Espera 0.3 segundos
Call led(_off, _nc)  'Apaga led_amarillo, no modifica led verde
Endif
Goto main  'Impide que termine la rutina principal
End                                               
'Calcula numeros aleatoriios, n_max = numero maximo y n_min = numero minimo
Const _on = 0  'Led encendido
Const _off = 1  'Led apagado
Const _nc = 2  'No cambia
Function random(n_max As Byte, n_min As Byte) As Byte
OPTION_REG.T0CS = 0  'Selecciona reloj interno
n_max = (n_max + 1) - n_min  'Arregla el numero maximo
random = (TMR0 Mod n_max) + n_min  'Siendo n_max el numero maximo y + n_min valor minimo
End Function                                     
'Controla el estado de los led, call (x,x)
Proc led(amarillo As Byte, verde As Byte)
If amarillo = 0 Then RA7 = 0  'Led amarillo a on
If amarillo = 1 Then RA7 = 1  'Led amarillo a off
If verde = 0 Then RB0 = 0  'Led verde a on
If verde = 1 Then RB0 = 1  'Led verde a off
End Proc


[xocas]

hola

lo primero, felicitaros por el trabajo que estáis realizando, que no es poco. es curioso porque desde siempre asocié el psi al amigo Ariel y llegué a creer que fuera el quien iniciara el tema. mis disculpas dogflu.

lo segundo, soy de los que -citando a maunix- lee, lee, lee y luego pregunta, así que antes de nada uno se lee los manuales y cualquier cosa que pueda y después que si encendemos un led, que si encendemos cuatro, y cuando nos atascamos y no entendemos porque, entonces se pregunta.

y así llegamos a la tercera parte, con un código de lo más tonto y asignando variables al tuntún me responde con errores de compilación en ciertas líneas cuyas variables observo que además ahora están en mayúsculas. Supongo que se trata de palabras reservadas pero no encuentro información en ningún lado que me lo confirme... os dejo un listado de las variables que dan errores por si podéis decirme algo al respecto. la versión que tengo es v6.65

Código: [Seleccionar]

'***********************************************
'Asignación de variables
'***********************************************
Dim a As Byte
Dim b As Byte
'Dim C As Byte --- Error: Incorrect variable name
'Dim D As Byte --- Error: Incorrect variable name
Dim e As Byte
'Dim F As Byte --- Error: Incorrect variable name
Dim g As Byte
Dim h As Byte
Dim i As Byte
Dim j As Byte
Dim k As Byte
Dim l As Byte
Dim m As Byte
Dim n As Byte
Dim o As Byte
'Dim P As Byte --- Error: Incorrect variable name
Dim q As Byte
'Dim R As Byte --- Error: Incorrect variable name
'Dim S As Byte --- Error: Incorrect variable name
Dim t As Byte
Dim u As Byte
Dim v As Byte
'Dim W As Byte --- Error: Incorrect variable name
Dim x As Byte
Dim y As Byte
'Dim Z As Byte --- Error: Incorrect variable name

'***********************************************
'Aparentan ser palabras reservadas pero no
'encuentro la documentación que me lo confirme
'***********************************************
un saludo y gracias

[aitopes]

Hola Xocas!

Es curioso lo de las variables. En general, salvo "i" para algun bucle, casi siempre uso nombres mas largos,tipo "cuenta", "suma", etc, por lo que no me habia pasado lo que mencionas.

Acabo de probar copiando y pegando tu trozo de codigo, y solo me da errores tipo "Incorrect Variable Name" en las siguientes cuatro: C, F, W,Z

En la ayuda ( http://www.oshonsoft.com/picbasiccompiler.html ) no se mencionan para nada, pero es cierto: al escribirlas, el editor automaticamente las pasa a mayusculas, asi que "algo hay". Lo extrano es que a mi me marca solo 4. Yo uso la version 6.65....¿cual tienes tu?

Por ultimo, probe hacer algo como

Symbol C = porta.1

y tambien dice que es un nombre de variable incorrecto. ¿Seran constantes? ¿O palabras reservadas?

Creo que constantes no son, por que al hacer

a = C

dice que "C no es una variable tipo xxx" para cualquier tipo de "a": bit, byte, word o Long.

Un misterio!

Saludos!

[dogflu66]

No se hace referencia en el manual, pero son todo registros reservados.
unos son registros, flag o tambien el nombre de un bit determinado de un registro.
Y todos tienen el mismo nombre que en el datasheet del pic en cuestion, por eso
segun el pic, si tiene estos registros o no el PSI nos dara error o no.